1# Version of AllTypes test case for protobuf 3 file format.
2
3Import("env")
4
5env.NanopbProto(["alltypes", "alltypes.options"])
6enc = env.Program(["encode_alltypes.c", "alltypes.pb.c", "$COMMON/pb_encode.o", "$COMMON/pb_common.o"])
7dec = env.Program(["decode_alltypes.c", "alltypes.pb.c", "$COMMON/pb_decode.o", "$COMMON/pb_common.o"])
8
9# Test the round-trip from nanopb encoder to nanopb decoder
10env.RunTest(enc)
11env.RunTest([dec, "encode_alltypes.output"])
12
13# Re-encode the data using protoc, and check that the results from nanopb
14# match byte-per-byte to the protoc output.
15env.Decode("encode_alltypes.output.decoded",
16           ["encode_alltypes.output", "alltypes.proto"],
17           MESSAGE='AllTypes')
18env.Encode("encode_alltypes.output.recoded",
19           ["encode_alltypes.output.decoded", "alltypes.proto"],
20           MESSAGE='AllTypes')
21env.Compare(["encode_alltypes.output", "encode_alltypes.output.recoded"])
22
23# Do the same checks with the optional fields present.
24env.RunTest("optionals.output", enc, ARGS = ['1'])
25env.RunTest("optionals.decout", [dec, "optionals.output"], ARGS = ['1'])
26env.Decode("optionals.output.decoded",
27           ["optionals.output", "alltypes.proto"],
28           MESSAGE='AllTypes')
29env.Encode("optionals.output.recoded",
30           ["optionals.output.decoded", "alltypes.proto"],
31           MESSAGE='AllTypes')
32env.Compare(["optionals.output", "optionals.output.recoded"])
33
34
35