1/*
2** ###################################################################
3**     Processors:          MIMX9352CVUXK_cm33
4**                          MIMX9352DVUXM_cm33
5**
6**     Compiler:            GNU C Compiler
7**     Reference manual:    IMX93RM, Internal, November. 2021
8**     Version:             rev. 1.0, 2021-11-16
9**     Build:               b220830
10**
11**     Abstract:
12**         Linker file for the GNU C Compiler
13**
14**     Copyright 2016 Freescale Semiconductor, Inc.
15**     Copyright 2016-2022 NXP
16**     All rights reserved.
17**
18**     SPDX-License-Identifier: BSD-3-Clause
19**
20**     http:                 www.nxp.com
21**     mail:                 support@nxp.com
22**
23** ###################################################################
24*/
25
26/* Entry Point */
27ENTRY(Reset_Handler)
28
29HEAP_SIZE  = DEFINED(__heap_size__)  ? __heap_size__  : 0x0400;
30STACK_SIZE = DEFINED(__stack_size__) ? __stack_size__ : 0x0400;
31M_VECTOR_RAM_SIZE = DEFINED(__ram_vector_table__) ? 0x0478 : 0x0;
32
33
34/* Specify the memory areas */
35MEMORY
36{
37  m_interrupts          (RX)  : ORIGIN = 0x0FFE0000, LENGTH = 0x00000478
38  m_text                (RX)  : ORIGIN = 0x0FFE0478, LENGTH = 0x0001FB88
39  m_data                (RW)  : ORIGIN = 0x20003000, LENGTH = 0x0001D000
40  m_m33_suspend_ram     (RW)  : ORIGIN = 0x20000000, LENGTH = 0x00002000
41  m_a55_suspend_ram     (RW)  : ORIGIN = 0x20002000, LENGTH = 0x00001000
42}
43
44/* Define output sections */
45SECTIONS
46{
47  /* The startup code goes first into internal RAM */
48  .interrupts :
49  {
50    __VECTOR_TABLE = .;
51    __Vectors = .;
52    . = ALIGN(4);
53    KEEP(*(.isr_vector))     /* Startup code */
54    . = ALIGN(4);
55  } > m_interrupts
56
57  .resource_table :
58  {
59    . = ALIGN(8);
60    KEEP(*(.resource_table)) /* Resource table */
61    . = ALIGN(8);
62  } > m_text
63
64  /* The program code and other data goes into internal RAM */
65  .text :
66  {
67    . = ALIGN(4);
68    *(.text)                 /* .text sections (code) */
69    *(.text*)                /* .text* sections (code) */
70    *(.rodata)               /* .rodata sections (constants, strings, etc.) */
71    *(.rodata*)              /* .rodata* sections (constants, strings, etc.) */
72    *(.glue_7)               /* glue arm to thumb code */
73    *(.glue_7t)              /* glue thumb to arm code */
74    *(.eh_frame)
75    KEEP (*(.init))
76    KEEP (*(.fini))
77    . = ALIGN(4);
78  } > m_text
79
80  .ARM.extab :
81  {
82    *(.ARM.extab* .gnu.linkonce.armextab.*)
83  } > m_text
84
85  .ARM :
86  {
87    __exidx_start = .;
88    *(.ARM.exidx*)
89    __exidx_end = .;
90  } > m_text
91
92 .ctors :
93  {
94    __CTOR_LIST__ = .;
95    /* gcc uses crtbegin.o to find the start of
96       the constructors, so we make sure it is
97       first.  Because this is a wildcard, it
98       doesn't matter if the user does not
99       actually link against crtbegin.o; the
100       linker won't look for a file to match a
101       wildcard.  The wildcard also means that it
102       doesn't matter which directory crtbegin.o
103       is in.  */
104    KEEP (*crtbegin.o(.ctors))
105    KEEP (*crtbegin?.o(.ctors))
106    /* We don't want to include the .ctor section from
107       from the crtend.o file until after the sorted ctors.
108       The .ctor section from the crtend file contains the
109       end of ctors marker and it must be last */
110    KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .ctors))
111    KEEP (*(SORT(.ctors.*)))
112    KEEP (*(.ctors))
113    __CTOR_END__ = .;
114  } > m_text
115
116  .dtors :
117  {
118    __DTOR_LIST__ = .;
119    KEEP (*crtbegin.o(.dtors))
120    KEEP (*crtbegin?.o(.dtors))
121    KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .dtors))
122    KEEP (*(SORT(.dtors.*)))
123    KEEP (*(.dtors))
124    __DTOR_END__ = .;
125  } > m_text
126
127  .preinit_array :
128  {
129    PROVIDE_HIDDEN (__preinit_array_start = .);
130    KEEP (*(.preinit_array*))
131    PROVIDE_HIDDEN (__preinit_array_end = .);
132  } > m_text
133
134  .init_array :
135  {
136    PROVIDE_HIDDEN (__init_array_start = .);
137    KEEP (*(SORT(.init_array.*)))
138    KEEP (*(.init_array*))
139    PROVIDE_HIDDEN (__init_array_end = .);
140  } > m_text
141
142  .fini_array :
143  {
144    PROVIDE_HIDDEN (__fini_array_start = .);
145    KEEP (*(SORT(.fini_array.*)))
146    KEEP (*(.fini_array*))
147    PROVIDE_HIDDEN (__fini_array_end = .);
148  } > m_text
149
150  __etext = .;    /* define a global symbol at end of code */
151  __DATA_ROM = .; /* Symbol is used by startup for data initialization */
152
153  .interrupts_ram :
154  {
155    . = ALIGN(4);
156    __VECTOR_RAM__ = .;
157    __interrupts_ram_start__ = .; /* Create a global symbol at data start */
158    *(.m_interrupts_ram)     /* This is a user defined section */
159    . += M_VECTOR_RAM_SIZE;
160    . = ALIGN(4);
161    __interrupts_ram_end__ = .; /* Define a global symbol at data end */
162  } > m_data
163
164  __VECTOR_RAM = DEFINED(__ram_vector_table__) ? __VECTOR_RAM__ : ORIGIN(m_interrupts);
165  __RAM_VECTOR_TABLE_SIZE_BYTES = DEFINED(__ram_vector_table__) ? (__interrupts_ram_end__ - __interrupts_ram_start__) : 0x0;
166
167  .data : AT(__DATA_ROM)
168  {
169    . = ALIGN(4);
170    __DATA_RAM = .;
171    __data_start__ = .;      /* create a global symbol at data start */
172    *(.data)                 /* .data sections */
173    *(.data*)                /* .data* sections */
174    KEEP(*(.jcr*))
175    . = ALIGN(4);
176    __data_end__ = .;        /* define a global symbol at data end */
177  } > m_data
178
179  __DATA_END = __DATA_ROM + (__data_end__ - __data_start__);
180  text_end = ORIGIN(m_text) + LENGTH(m_text);
181  ASSERT(__DATA_END <= text_end, "region m_text overflowed with text and data")
182
183  /* Uninitialized data section */
184  .bss :
185  {
186    /* This is used by the startup in order to initialize the .bss section */
187    . = ALIGN(4);
188    __START_BSS = .;
189    __bss_start__ = .;
190    *(.bss)
191    *(.bss*)
192    *(COMMON)
193    . = ALIGN(4);
194    __bss_end__ = .;
195    __END_BSS = .;
196  } > m_data
197
198  .m33_suspend :
199  {
200    *(M33SuspendRam)
201    . = ALIGN(4);
202  } > m_m33_suspend_ram
203
204  .heap :
205  {
206    . = ALIGN(8);
207    __end__ = .;
208    PROVIDE(end = .);
209    __HeapBase = .;
210    . += HEAP_SIZE;
211    __HeapLimit = .;
212    __heap_limit = .; /* Add for _sbrk */
213  } > m_data
214
215  .stack :
216  {
217    . = ALIGN(8);
218    . += STACK_SIZE;
219  } > m_data
220
221  /* Initializes stack on the end of block */
222  __StackTop   = ORIGIN(m_data) + LENGTH(m_data);
223  __StackLimit = __StackTop - STACK_SIZE;
224  PROVIDE(__stack = __StackTop);
225
226  .ARM.attributes 0 : { *(.ARM.attributes) }
227
228  ASSERT(__StackLimit >= __HeapLimit, "region m_data overflowed with stack and heap")
229}
230