1/*
2** ###################################################################
3**     Processors:          LPC822M101JDH20
4**                          LPC822M101JHI33
5**
6**     Compiler:            GNU C Compiler
7**     Reference manual:    LPC82x User manual Rev.1.2  5 October 2016
8**     Version:             rev. 1.0, 2017-10-17
9**     Build:               b200408
10**
11**     Abstract:
12**         Linker file for the GNU C Compiler
13**
14**     Copyright 2016 Freescale Semiconductor, Inc.
15**     Copyright 2016-2020 NXP
16**     All rights reserved.
17**
18**     SPDX-License-Identifier: BSD-3-Clause
19**
20**     http:                 www.nxp.com
21**     mail:                 support@nxp.com
22**
23** ###################################################################
24*/
25
26
27
28/* Entry Point */
29ENTRY(Reset_Handler)
30
31HEAP_SIZE  = DEFINED(__heap_size__)  ? __heap_size__  : 0x0400;
32STACK_SIZE = DEFINED(__stack_size__) ? __stack_size__ : 0x0800;
33
34/* Specify the memory areas */
35MEMORY
36{
37  m_interrupts          (RX)  : ORIGIN = 0x00000000, LENGTH = 0x00000200
38  m_crp                 (RX)  : ORIGIN = 0x000002FC, LENGTH = 0x00000004
39  m_text                (RX)  : ORIGIN = 0x00000300, LENGTH = 0x00003D00
40  m_data                (RW)  : ORIGIN = 0x10000000, LENGTH = 0x00000FE0
41}
42
43/* Define output sections */
44SECTIONS
45{
46  /* The startup code goes first into internal flash */
47  .interrupts :
48  {
49    . = ALIGN(4);
50    KEEP(*(.isr_vector))     /* Startup code */
51    . = ALIGN(4);
52  } > m_interrupts
53
54  .crp :
55  {
56    . = ALIGN(4);
57    KEEP(*(.crp))    /* Code Read Protection level (CRP) */
58    . = ALIGN(4);
59  } > m_crp
60
61  /* The program code and other data goes into internal flash */
62  .text :
63  {
64    . = ALIGN(4);
65    *(.text)                 /* .text sections (code) */
66    *(.text*)                /* .text* sections (code) */
67    *(.rodata)               /* .rodata sections (constants, strings, etc.) */
68    *(.rodata*)              /* .rodata* sections (constants, strings, etc.) */
69    *(.glue_7)               /* glue arm to thumb code */
70    *(.glue_7t)              /* glue thumb to arm code */
71    *(.eh_frame)
72    KEEP (*(.init))
73    KEEP (*(.fini))
74    . = ALIGN(4);
75  } > m_text
76
77  .ARM.extab :
78  {
79    *(.ARM.extab* .gnu.linkonce.armextab.*)
80  } > m_text
81
82  .ARM :
83  {
84    __exidx_start = .;
85    *(.ARM.exidx*)
86    __exidx_end = .;
87  } > m_text
88
89 .ctors :
90  {
91    __CTOR_LIST__ = .;
92    /* gcc uses crtbegin.o to find the start of
93       the constructors, so we make sure it is
94       first.  Because this is a wildcard, it
95       doesn't matter if the user does not
96       actually link against crtbegin.o; the
97       linker won't look for a file to match a
98       wildcard.  The wildcard also means that it
99       doesn't matter which directory crtbegin.o
100       is in.  */
101    KEEP (*crtbegin.o(.ctors))
102    KEEP (*crtbegin?.o(.ctors))
103    /* We don't want to include the .ctor section from
104       from the crtend.o file until after the sorted ctors.
105       The .ctor section from the crtend file contains the
106       end of ctors marker and it must be last */
107    KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .ctors))
108    KEEP (*(SORT(.ctors.*)))
109    KEEP (*(.ctors))
110    __CTOR_END__ = .;
111  } > m_text
112
113  .dtors :
114  {
115    __DTOR_LIST__ = .;
116    KEEP (*crtbegin.o(.dtors))
117    KEEP (*crtbegin?.o(.dtors))
118    KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .dtors))
119    KEEP (*(SORT(.dtors.*)))
120    KEEP (*(.dtors))
121    __DTOR_END__ = .;
122  } > m_text
123
124  .preinit_array :
125  {
126    PROVIDE_HIDDEN (__preinit_array_start = .);
127    KEEP (*(.preinit_array*))
128    PROVIDE_HIDDEN (__preinit_array_end = .);
129  } > m_text
130
131  .init_array :
132  {
133    PROVIDE_HIDDEN (__init_array_start = .);
134    KEEP (*(SORT(.init_array.*)))
135    KEEP (*(.init_array*))
136    PROVIDE_HIDDEN (__init_array_end = .);
137  } > m_text
138
139  .fini_array :
140  {
141    PROVIDE_HIDDEN (__fini_array_start = .);
142    KEEP (*(SORT(.fini_array.*)))
143    KEEP (*(.fini_array*))
144    PROVIDE_HIDDEN (__fini_array_end = .);
145  } > m_text
146
147  __etext = .;    /* define a global symbol at end of code */
148  __DATA_ROM = .; /* Symbol is used by startup for data initialization */
149
150  .data : AT(__DATA_ROM)
151  {
152    . = ALIGN(4);
153    __DATA_RAM = .;
154    __data_start__ = .;      /* create a global symbol at data start */
155    *(.ramfunc*)             /* for functions in ram */
156    *(.data)                 /* .data sections */
157    *(.data*)                /* .data* sections */
158    KEEP(*(.jcr*))
159    . = ALIGN(4);
160    __data_end__ = .;        /* define a global symbol at data end */
161  } > m_data
162
163  __DATA_END = __DATA_ROM + (__data_end__ - __data_start__);
164  text_end = ORIGIN(m_text) + LENGTH(m_text);
165  ASSERT(__DATA_END <= text_end, "region m_text overflowed with text and data")
166
167  /* Uninitialized data section */
168  .bss :
169  {
170    /* This is used by the startup in order to initialize the .bss section */
171    . = ALIGN(4);
172    __START_BSS = .;
173    __bss_start__ = .;
174    *(.bss)
175    *(.bss*)
176    *(COMMON)
177    . = ALIGN(4);
178    __bss_end__ = .;
179    __END_BSS = .;
180  } > m_data
181
182  .heap :
183  {
184    . = ALIGN(8);
185    __end__ = .;
186    PROVIDE(end = .);
187    __HeapBase = .;
188    . += HEAP_SIZE;
189    __HeapLimit = .;
190    __heap_limit = .; /* Add for _sbrk */
191  } > m_data
192
193  .stack :
194  {
195    . = ALIGN(8);
196    . += STACK_SIZE;
197  } > m_data
198
199  /* Initializes stack on the end of block */
200  __StackTop   = ORIGIN(m_data) + LENGTH(m_data);
201  __StackLimit = __StackTop - STACK_SIZE;
202  PROVIDE(__stack = __StackTop);
203
204  .ARM.attributes 0 : { *(.ARM.attributes) }
205
206  ASSERT(__StackLimit >= __HeapLimit, "region m_data overflowed with stack and heap")
207}
208
209