1/*
2** ###################################################################
3**     Processors:          LPC804M101JDH20
4**                          LPC804M101JDH24
5**                          LPC804M101JHI33
6**                          LPC804M111JDH24
7**                          LPC804UK
8**
9**     Compiler:            GNU C Compiler
10**     Reference manual:    LPC804 User manual Rev.1.0  24 Jan 2018
11**     Version:             rev. 1.0, 2018-01-09
12**     Build:               b200408
13**
14**     Abstract:
15**         Linker file for the GNU C Compiler
16**
17**     Copyright 2016 Freescale Semiconductor, Inc.
18**     Copyright 2016-2020 NXP
19**     All rights reserved.
20**
21**     SPDX-License-Identifier: BSD-3-Clause
22**
23**     http:                 www.nxp.com
24**     mail:                 support@nxp.com
25**
26** ###################################################################
27*/
28
29
30
31/* Entry Point */
32ENTRY(Reset_Handler)
33
34HEAP_SIZE  = DEFINED(__heap_size__)  ? __heap_size__  : 0x040;
35STACK_SIZE = DEFINED(__stack_size__) ? __stack_size__ : 0x040;
36
37/* Specify the memory areas */
38MEMORY
39{
40  m_interrupts          (RX)  : ORIGIN = 0x00000000, LENGTH = 0x00000200
41  m_crp                 (RX)  : ORIGIN = 0x000002FC, LENGTH = 0x00000004
42  m_text                (RX)  : ORIGIN = 0x00000300, LENGTH = 0x00007C00
43  m_data                (RW)  : ORIGIN = 0x10000000, LENGTH = 0x00000FE0
44}
45
46/* Define output sections */
47SECTIONS
48{
49  /* The startup code goes first into internal flash */
50  .interrupts :
51  {
52    . = ALIGN(4);
53    KEEP(*(.isr_vector))     /* Startup code */
54    . = ALIGN(4);
55  } > m_interrupts
56
57  .crp :
58  {
59    . = ALIGN(4);
60    KEEP(*(.crp))    /* Code Read Protection level (CRP) */
61    . = ALIGN(4);
62  } > m_crp
63
64  /* The program code and other data goes into internal flash */
65  .text :
66  {
67    . = ALIGN(4);
68    *(.text)                 /* .text sections (code) */
69    *(.text*)                /* .text* sections (code) */
70    *(.rodata)               /* .rodata sections (constants, strings, etc.) */
71    *(.rodata*)              /* .rodata* sections (constants, strings, etc.) */
72    *(.glue_7)               /* glue arm to thumb code */
73    *(.glue_7t)              /* glue thumb to arm code */
74    *(.eh_frame)
75    KEEP (*(.init))
76    KEEP (*(.fini))
77    . = ALIGN(4);
78  } > m_text
79
80  .ARM.extab :
81  {
82    *(.ARM.extab* .gnu.linkonce.armextab.*)
83  } > m_text
84
85  .ARM :
86  {
87    __exidx_start = .;
88    *(.ARM.exidx*)
89    __exidx_end = .;
90  } > m_text
91
92 .ctors :
93  {
94    __CTOR_LIST__ = .;
95    /* gcc uses crtbegin.o to find the start of
96       the constructors, so we make sure it is
97       first.  Because this is a wildcard, it
98       doesn't matter if the user does not
99       actually link against crtbegin.o; the
100       linker won't look for a file to match a
101       wildcard.  The wildcard also means that it
102       doesn't matter which directory crtbegin.o
103       is in.  */
104    KEEP (*crtbegin.o(.ctors))
105    KEEP (*crtbegin?.o(.ctors))
106    /* We don't want to include the .ctor section from
107       from the crtend.o file until after the sorted ctors.
108       The .ctor section from the crtend file contains the
109       end of ctors marker and it must be last */
110    KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .ctors))
111    KEEP (*(SORT(.ctors.*)))
112    KEEP (*(.ctors))
113    __CTOR_END__ = .;
114  } > m_text
115
116  .dtors :
117  {
118    __DTOR_LIST__ = .;
119    KEEP (*crtbegin.o(.dtors))
120    KEEP (*crtbegin?.o(.dtors))
121    KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .dtors))
122    KEEP (*(SORT(.dtors.*)))
123    KEEP (*(.dtors))
124    __DTOR_END__ = .;
125  } > m_text
126
127  .preinit_array :
128  {
129    PROVIDE_HIDDEN (__preinit_array_start = .);
130    KEEP (*(.preinit_array*))
131    PROVIDE_HIDDEN (__preinit_array_end = .);
132  } > m_text
133
134  .init_array :
135  {
136    PROVIDE_HIDDEN (__init_array_start = .);
137    KEEP (*(SORT(.init_array.*)))
138    KEEP (*(.init_array*))
139    PROVIDE_HIDDEN (__init_array_end = .);
140  } > m_text
141
142  .fini_array :
143  {
144    PROVIDE_HIDDEN (__fini_array_start = .);
145    KEEP (*(SORT(.fini_array.*)))
146    KEEP (*(.fini_array*))
147    PROVIDE_HIDDEN (__fini_array_end = .);
148  } > m_text
149
150  __etext = .;    /* define a global symbol at end of code */
151  __DATA_ROM = .; /* Symbol is used by startup for data initialization */
152
153  .data : AT(__DATA_ROM)
154  {
155    . = ALIGN(4);
156    __DATA_RAM = .;
157    __data_start__ = .;      /* create a global symbol at data start */
158    *(.ramfunc*)             /* for functions in ram */
159    *(.data)                 /* .data sections */
160    *(.data*)                /* .data* sections */
161    KEEP(*(.jcr*))
162    . = ALIGN(4);
163    __data_end__ = .;        /* define a global symbol at data end */
164  } > m_data
165
166  __DATA_END = __DATA_ROM + (__data_end__ - __data_start__);
167  text_end = ORIGIN(m_text) + LENGTH(m_text);
168  ASSERT(__DATA_END <= text_end, "region m_text overflowed with text and data")
169
170  /* Uninitialized data section */
171  .bss :
172  {
173    /* This is used by the startup in order to initialize the .bss section */
174    . = ALIGN(4);
175    __START_BSS = .;
176    __bss_start__ = .;
177    *(.bss)
178    *(.bss*)
179    *(COMMON)
180    . = ALIGN(4);
181    __bss_end__ = .;
182    __END_BSS = .;
183  } > m_data
184
185  .heap :
186  {
187    . = ALIGN(8);
188    __end__ = .;
189    PROVIDE(end = .);
190    __HeapBase = .;
191    . += HEAP_SIZE;
192    __HeapLimit = .;
193    __heap_limit = .; /* Add for _sbrk */
194  } > m_data
195
196  .stack :
197  {
198    . = ALIGN(8);
199    . += STACK_SIZE;
200  } > m_data
201
202  /* Initializes stack on the end of block */
203  __StackTop   = ORIGIN(m_data) + LENGTH(m_data);
204  __StackLimit = __StackTop - STACK_SIZE;
205  PROVIDE(__stack = __StackTop);
206
207  .ARM.attributes 0 : { *(.ARM.attributes) }
208
209  ASSERT(__StackLimit >= __HeapLimit, "region m_data overflowed with stack and heap")
210}
211
212