1/*
2** ###################################################################
3**     Processors:          LPC51U68JBD48
4**                          LPC51U68JBD64
5**
6**     Compiler:            GNU C Compiler
7**     Reference manual:    LPC51U68 User manual User manual Rev. 1.0 13 Dec 2017
8**     Version:             rev. 1.0, 2017-12-15
9**     Build:               b200408
10**
11**     Abstract:
12**         Linker file for the GNU C Compiler
13**
14**     Copyright 2016 Freescale Semiconductor, Inc.
15**     Copyright 2016-2020 NXP
16**     All rights reserved.
17**
18**     SPDX-License-Identifier: BSD-3-Clause
19**
20**     http:                 www.nxp.com
21**     mail:                 support@nxp.com
22**
23** ###################################################################
24*/
25
26
27
28/* Entry Point */
29ENTRY(Reset_Handler)
30
31HEAP_SIZE  = DEFINED(__heap_size__)  ? __heap_size__  : 0x0400;
32STACK_SIZE = DEFINED(__stack_size__) ? __stack_size__ : 0x0800;
33
34/* Specify the memory areas */
35MEMORY
36{
37  m_interrupts          (RX)  : ORIGIN = 0x00000000, LENGTH = 0x00000200
38  m_crp                 (RX)  : ORIGIN = 0x000002FC, LENGTH = 0x00000004
39  m_text                (RX)  : ORIGIN = 0x00000300, LENGTH = 0x0003FD00
40  m_data_sramx          (RW)  : ORIGIN = 0x04000000, LENGTH = 0x00008000
41  m_data                (RW)  : ORIGIN = 0x20000000, LENGTH = 0x00010000
42}
43
44/* Define output sections */
45SECTIONS
46{
47  /* The startup code goes first into internal flash */
48  .interrupts :
49  {
50    . = ALIGN(4);
51    KEEP(*(.isr_vector))     /* Startup code */
52    . = ALIGN(4);
53  } > m_interrupts
54
55  .crp :
56  {
57    . = ALIGN(4);
58    KEEP(*(.crp))    /* Code Read Protection level (CRP) */
59    . = ALIGN(4);
60  } > m_crp
61
62  /* The program code and other data goes into internal flash */
63  .text :
64  {
65    . = ALIGN(4);
66    *(.text)                 /* .text sections (code) */
67    *(.text*)                /* .text* sections (code) */
68    *(.rodata)               /* .rodata sections (constants, strings, etc.) */
69    *(.rodata*)              /* .rodata* sections (constants, strings, etc.) */
70    *(.glue_7)               /* glue arm to thumb code */
71    *(.glue_7t)              /* glue thumb to arm code */
72    *(.eh_frame)
73    KEEP (*(.init))
74    KEEP (*(.fini))
75    . = ALIGN(4);
76  } > m_text
77
78  .ARM.extab :
79  {
80    *(.ARM.extab* .gnu.linkonce.armextab.*)
81  } > m_text
82
83  .ARM :
84  {
85    __exidx_start = .;
86    *(.ARM.exidx*)
87    __exidx_end = .;
88  } > m_text
89
90 .ctors :
91  {
92    __CTOR_LIST__ = .;
93    /* gcc uses crtbegin.o to find the start of
94       the constructors, so we make sure it is
95       first.  Because this is a wildcard, it
96       doesn't matter if the user does not
97       actually link against crtbegin.o; the
98       linker won't look for a file to match a
99       wildcard.  The wildcard also means that it
100       doesn't matter which directory crtbegin.o
101       is in.  */
102    KEEP (*crtbegin.o(.ctors))
103    KEEP (*crtbegin?.o(.ctors))
104    /* We don't want to include the .ctor section from
105       from the crtend.o file until after the sorted ctors.
106       The .ctor section from the crtend file contains the
107       end of ctors marker and it must be last */
108    KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .ctors))
109    KEEP (*(SORT(.ctors.*)))
110    KEEP (*(.ctors))
111    __CTOR_END__ = .;
112  } > m_text
113
114  .dtors :
115  {
116    __DTOR_LIST__ = .;
117    KEEP (*crtbegin.o(.dtors))
118    KEEP (*crtbegin?.o(.dtors))
119    KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .dtors))
120    KEEP (*(SORT(.dtors.*)))
121    KEEP (*(.dtors))
122    __DTOR_END__ = .;
123  } > m_text
124
125  .preinit_array :
126  {
127    PROVIDE_HIDDEN (__preinit_array_start = .);
128    KEEP (*(.preinit_array*))
129    PROVIDE_HIDDEN (__preinit_array_end = .);
130  } > m_text
131
132  .init_array :
133  {
134    PROVIDE_HIDDEN (__init_array_start = .);
135    KEEP (*(SORT(.init_array.*)))
136    KEEP (*(.init_array*))
137    PROVIDE_HIDDEN (__init_array_end = .);
138  } > m_text
139
140  .fini_array :
141  {
142    PROVIDE_HIDDEN (__fini_array_start = .);
143    KEEP (*(SORT(.fini_array.*)))
144    KEEP (*(.fini_array*))
145    PROVIDE_HIDDEN (__fini_array_end = .);
146  } > m_text
147
148  __etext = .;    /* define a global symbol at end of code */
149  __DATA_ROM = .; /* Symbol is used by startup for data initialization */
150
151  .data : AT(__DATA_ROM)
152  {
153    . = ALIGN(4);
154    __DATA_RAM = .;
155    __data_start__ = .;      /* create a global symbol at data start */
156    *(.ramfunc*)             /* for functions in ram */
157    *(.data)                 /* .data sections */
158    *(.data*)                /* .data* sections */
159    KEEP(*(.jcr*))
160    . = ALIGN(4);
161    __data_end__ = .;        /* define a global symbol at data end */
162  } > m_data
163
164  __DATA_END = __DATA_ROM + (__data_end__ - __data_start__);
165  text_end = ORIGIN(m_text) + LENGTH(m_text);
166  ASSERT(__DATA_END <= text_end, "region m_text overflowed with text and data")
167
168  /* Uninitialized data section */
169  .bss :
170  {
171    /* This is used by the startup in order to initialize the .bss section */
172    . = ALIGN(4);
173    __START_BSS = .;
174    __bss_start__ = .;
175    *(.bss)
176    *(.bss*)
177    *(COMMON)
178    . = ALIGN(4);
179    __bss_end__ = .;
180    __END_BSS = .;
181  } > m_data
182
183  .heap :
184  {
185    . = ALIGN(8);
186    __end__ = .;
187    PROVIDE(end = .);
188    __HeapBase = .;
189    . += HEAP_SIZE;
190    __HeapLimit = .;
191    __heap_limit = .; /* Add for _sbrk */
192  } > m_data_sramx
193
194  .stack :
195  {
196    . = ALIGN(8);
197    . += STACK_SIZE;
198  } > m_data_sramx
199
200  /* Initializes stack on the end of block */
201  __StackTop   = ORIGIN(m_data_sramx) + LENGTH(m_data_sramx);
202  __StackLimit = __StackTop - STACK_SIZE;
203  PROVIDE(__stack = __StackTop);
204
205  .ARM.attributes 0 : { *(.ARM.attributes) }
206
207  ASSERT(__StackLimit >= __HeapLimit, "region m_data_sramx overflowed with stack and heap")
208}
209
210