1/*
2** ###################################################################
3**     Processors:          MKV30F128VFM10
4**                          MKV30F128VLF10
5**                          MKV30F128VLH10
6**
7**     Compiler:            GNU C Compiler
8**     Reference manual:    KV30P64M100SFARM, Rev. 0, February 14, 2014
9**     Version:             rev. 0.5, 2015-02-19
10**     Build:               b210812
11**
12**     Abstract:
13**         Linker file for the GNU C Compiler
14**
15**     Copyright 2016 Freescale Semiconductor, Inc.
16**     Copyright 2016-2021 NXP
17**     All rights reserved.
18**
19**     SPDX-License-Identifier: BSD-3-Clause
20**
21**     http:                 www.nxp.com
22**     mail:                 support@nxp.com
23**
24** ###################################################################
25*/
26
27/* Entry Point */
28ENTRY(Reset_Handler)
29
30HEAP_SIZE  = DEFINED(__heap_size__)  ? __heap_size__  : 0x0400;
31STACK_SIZE = DEFINED(__stack_size__) ? __stack_size__ : 0x0400;
32
33/* Specify the memory areas */
34MEMORY
35{
36  m_interrupts          (RX)  : ORIGIN = 0x1FFFE000, LENGTH = 0x00000400
37  m_text                (RX)  : ORIGIN = 0x1FFFE400, LENGTH = 0x00001C00
38  m_data                (RW)  : ORIGIN = 0x20000000, LENGTH = 0x00002000
39}
40
41/* Define output sections */
42SECTIONS
43{
44  /* The startup code goes first into internal RAM */
45  .interrupts :
46  {
47    . = ALIGN(4);
48    KEEP(*(.isr_vector))     /* Startup code */
49    . = ALIGN(4);
50  } > m_interrupts
51
52  /* The program code and other data goes into internal RAM */
53  .text :
54  {
55    . = ALIGN(4);
56    *(.text)                 /* .text sections (code) */
57    *(.text*)                /* .text* sections (code) */
58    *(.rodata)               /* .rodata sections (constants, strings, etc.) */
59    *(.rodata*)              /* .rodata* sections (constants, strings, etc.) */
60    *(.glue_7)               /* glue arm to thumb code */
61    *(.glue_7t)              /* glue thumb to arm code */
62    *(.eh_frame)
63    KEEP (*(.init))
64    KEEP (*(.fini))
65    . = ALIGN(4);
66  } > m_text
67
68  .ARM.extab :
69  {
70    *(.ARM.extab* .gnu.linkonce.armextab.*)
71  } > m_text
72
73  .ARM :
74  {
75    __exidx_start = .;
76    *(.ARM.exidx*)
77    __exidx_end = .;
78  } > m_text
79
80 .ctors :
81  {
82    __CTOR_LIST__ = .;
83    /* gcc uses crtbegin.o to find the start of
84       the constructors, so we make sure it is
85       first.  Because this is a wildcard, it
86       doesn't matter if the user does not
87       actually link against crtbegin.o; the
88       linker won't look for a file to match a
89       wildcard.  The wildcard also means that it
90       doesn't matter which directory crtbegin.o
91       is in.  */
92    KEEP (*crtbegin.o(.ctors))
93    KEEP (*crtbegin?.o(.ctors))
94    /* We don't want to include the .ctor section from
95       from the crtend.o file until after the sorted ctors.
96       The .ctor section from the crtend file contains the
97       end of ctors marker and it must be last */
98    KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .ctors))
99    KEEP (*(SORT(.ctors.*)))
100    KEEP (*(.ctors))
101    __CTOR_END__ = .;
102  } > m_text
103
104  .dtors :
105  {
106    __DTOR_LIST__ = .;
107    KEEP (*crtbegin.o(.dtors))
108    KEEP (*crtbegin?.o(.dtors))
109    KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .dtors))
110    KEEP (*(SORT(.dtors.*)))
111    KEEP (*(.dtors))
112    __DTOR_END__ = .;
113  } > m_text
114
115  .preinit_array :
116  {
117    PROVIDE_HIDDEN (__preinit_array_start = .);
118    KEEP (*(.preinit_array*))
119    PROVIDE_HIDDEN (__preinit_array_end = .);
120  } > m_text
121
122  .init_array :
123  {
124    PROVIDE_HIDDEN (__init_array_start = .);
125    KEEP (*(SORT(.init_array.*)))
126    KEEP (*(.init_array*))
127    PROVIDE_HIDDEN (__init_array_end = .);
128  } > m_text
129
130  .fini_array :
131  {
132    PROVIDE_HIDDEN (__fini_array_start = .);
133    KEEP (*(SORT(.fini_array.*)))
134    KEEP (*(.fini_array*))
135    PROVIDE_HIDDEN (__fini_array_end = .);
136  } > m_text
137
138  __etext = .;    /* define a global symbol at end of code */
139  __DATA_ROM = .; /* Symbol is used by startup for data initialization */
140
141  .data : AT(__DATA_ROM)
142  {
143    . = ALIGN(4);
144    __DATA_RAM = .;
145    __data_start__ = .;      /* create a global symbol at data start */
146    *(.data)                 /* .data sections */
147    *(.data*)                /* .data* sections */
148    *(NonCacheable.init)     /* NonCacheable init section */
149    *(NonCacheable)          /* NonCacheable section */
150    *(CodeQuickAccess)       /* quick access code section */
151    *(DataQuickAccess)       /* quick access data section */
152    KEEP(*(.jcr*))
153    . = ALIGN(4);
154    __data_end__ = .;        /* define a global symbol at data end */
155  } > m_data
156
157  __DATA_END = __DATA_ROM + (__data_end__ - __data_start__);
158  text_end = ORIGIN(m_text) + LENGTH(m_text);
159  ASSERT(__DATA_END <= text_end, "region m_text overflowed with text and data")
160
161  /* Uninitialized data section */
162  .bss :
163  {
164    /* This is used by the startup in order to initialize the .bss section */
165    . = ALIGN(4);
166    __START_BSS = .;
167    __bss_start__ = .;
168    *(.bss)
169    *(.bss*)
170    *(COMMON)
171    . = ALIGN(4);
172    __bss_end__ = .;
173    __END_BSS = .;
174  } > m_data
175
176  .heap :
177  {
178    . = ALIGN(8);
179    __end__ = .;
180    PROVIDE(end = .);
181    __HeapBase = .;
182    . += HEAP_SIZE;
183    __HeapLimit = .;
184    __heap_limit = .; /* Add for _sbrk */
185  } > m_data
186
187  .stack :
188  {
189    . = ALIGN(8);
190    . += STACK_SIZE;
191  } > m_data
192
193  /* Initializes stack on the end of block */
194  __StackTop   = ORIGIN(m_data) + LENGTH(m_data);
195  __StackLimit = __StackTop - STACK_SIZE;
196  PROVIDE(__stack = __StackTop);
197
198  .ARM.attributes 0 : { *(.ARM.attributes) }
199
200  ASSERT(__StackLimit >= __HeapLimit, "region m_data overflowed with stack and heap")
201}
202
203