1/*
2** ###################################################################
3**     Processors:          MIMXRT1176AVM8A_cm4
4**                          MIMXRT1176CVM8A_cm4
5**                          MIMXRT1176DVMAA_cm4
6**
7**     Compiler:            GNU C Compiler
8**     Reference manual:    IMXRT1170RM, Rev 1, 02/2021
9**     Version:             rev. 1.1, 2022-04-02
10**     Build:               b220402
11**
12**     Abstract:
13**         Linker file for the GNU C Compiler
14**
15**     Copyright 2016 Freescale Semiconductor, Inc.
16**     Copyright 2016-2022 NXP
17**     All rights reserved.
18**
19**     SPDX-License-Identifier: BSD-3-Clause
20**
21**     http:                 www.nxp.com
22**     mail:                 support@nxp.com
23**
24** ###################################################################
25*/
26
27/* Entry Point */
28ENTRY(Reset_Handler)
29
30HEAP_SIZE  = DEFINED(__heap_size__)  ? __heap_size__  : 0x0400;
31STACK_SIZE = DEFINED(__stack_size__) ? __stack_size__ : 0x0400;
32NCACHE_HEAP_START = DEFINED(__heap_noncacheable__) ? 0x84000000 - HEAP_SIZE : 0x202C0000 - HEAP_SIZE;
33NCACHE_HEAP_SIZE  = DEFINED(__heap_noncacheable__) ? HEAP_SIZE : 0x0000;
34
35/* Specify the memory areas */
36MEMORY
37{
38  m_interrupts          (RX)  : ORIGIN = 0x80000000, LENGTH = 0x00000400
39  m_text                (RX)  : ORIGIN = 0x80000400, LENGTH = 0x001FFC00
40  m_qacode              (RX)  : ORIGIN = 0x1FFE0000, LENGTH = 0x00020000
41  m_data                (RW)  : ORIGIN = 0x20240000, LENGTH = DEFINED(__heap_noncacheable__) ? 0x00080000 : 0x00080000 - HEAP_SIZE
42  m_data2               (RW)  : ORIGIN = 0x20000000, LENGTH = 0x00020000
43  m_data3               (RW)  : ORIGIN = 0x80200000, LENGTH = 0x02E00000
44  m_ncache              (RW)  : ORIGIN = 0x83000000, LENGTH = DEFINED(__heap_noncacheable__) ? 0x01000000 - HEAP_SIZE : 0x01000000
45  m_heap                (RW)  : ORIGIN = NCACHE_HEAP_START, LENGTH = HEAP_SIZE
46}
47
48/* Define output sections */
49SECTIONS
50{
51  __NCACHE_REGION_START = ORIGIN(m_ncache);
52  __NCACHE_REGION_SIZE  = LENGTH(m_ncache) + NCACHE_HEAP_SIZE;
53
54  /* The startup code goes first into internal RAM */
55  .interrupts :
56  {
57    __VECTOR_TABLE = .;
58    __Vectors = .;
59    . = ALIGN(4);
60    KEEP(*(.isr_vector))     /* Startup code */
61    . = ALIGN(4);
62  } > m_interrupts
63
64  /* The program code and other data goes into internal RAM */
65  .text :
66  {
67    . = ALIGN(4);
68    *(.text)                 /* .text sections (code) */
69    *(.text*)                /* .text* sections (code) */
70    *(.rodata)               /* .rodata sections (constants, strings, etc.) */
71    *(.rodata*)              /* .rodata* sections (constants, strings, etc.) */
72    *(.glue_7)               /* glue arm to thumb code */
73    *(.glue_7t)              /* glue thumb to arm code */
74    *(.eh_frame)
75    KEEP (*(.init))
76    KEEP (*(.fini))
77    . = ALIGN(4);
78  } > m_text
79
80  .ARM.extab :
81  {
82    *(.ARM.extab* .gnu.linkonce.armextab.*)
83  } > m_text
84
85  .ARM :
86  {
87    __exidx_start = .;
88    *(.ARM.exidx*)
89    __exidx_end = .;
90  } > m_text
91
92 .ctors :
93  {
94    __CTOR_LIST__ = .;
95    /* gcc uses crtbegin.o to find the start of
96       the constructors, so we make sure it is
97       first.  Because this is a wildcard, it
98       doesn't matter if the user does not
99       actually link against crtbegin.o; the
100       linker won't look for a file to match a
101       wildcard.  The wildcard also means that it
102       doesn't matter which directory crtbegin.o
103       is in.  */
104    KEEP (*crtbegin.o(.ctors))
105    KEEP (*crtbegin?.o(.ctors))
106    /* We don't want to include the .ctor section from
107       from the crtend.o file until after the sorted ctors.
108       The .ctor section from the crtend file contains the
109       end of ctors marker and it must be last */
110    KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .ctors))
111    KEEP (*(SORT(.ctors.*)))
112    KEEP (*(.ctors))
113    __CTOR_END__ = .;
114  } > m_text
115
116  .dtors :
117  {
118    __DTOR_LIST__ = .;
119    KEEP (*crtbegin.o(.dtors))
120    KEEP (*crtbegin?.o(.dtors))
121    KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .dtors))
122    KEEP (*(SORT(.dtors.*)))
123    KEEP (*(.dtors))
124    __DTOR_END__ = .;
125  } > m_text
126
127  .preinit_array :
128  {
129    PROVIDE_HIDDEN (__preinit_array_start = .);
130    KEEP (*(.preinit_array*))
131    PROVIDE_HIDDEN (__preinit_array_end = .);
132  } > m_text
133
134  .init_array :
135  {
136    PROVIDE_HIDDEN (__init_array_start = .);
137    KEEP (*(SORT(.init_array.*)))
138    KEEP (*(.init_array*))
139    PROVIDE_HIDDEN (__init_array_end = .);
140  } > m_text
141
142  .fini_array :
143  {
144    PROVIDE_HIDDEN (__fini_array_start = .);
145    KEEP (*(SORT(.fini_array.*)))
146    KEEP (*(.fini_array*))
147    PROVIDE_HIDDEN (__fini_array_end = .);
148  } > m_text
149
150  __etext = .;    /* define a global symbol at end of code */
151  __DATA_ROM = .; /* Symbol is used by startup for data initialization */
152
153  __VECTOR_RAM = ORIGIN(m_interrupts);
154  __RAM_VECTOR_TABLE_SIZE_BYTES = 0x0;
155
156  .data : AT(__DATA_ROM)
157  {
158    . = ALIGN(4);
159    __DATA_RAM = .;
160    __data_start__ = .;      /* create a global symbol at data start */
161    *(m_usb_dma_init_data)
162    *(.data)                 /* .data sections */
163    *(.data*)                /* .data* sections */
164    KEEP(*(.jcr*))
165    . = ALIGN(4);
166    __data_end__ = .;        /* define a global symbol at data end */
167  } > m_data
168
169  __ram_function_flash_start = __DATA_ROM + (__data_end__ - __data_start__); /* Symbol is used by startup for TCM data initialization */
170
171  .ram_function : AT(__ram_function_flash_start)
172  {
173    . = ALIGN(32);
174    __ram_function_start__ = .;
175    *(CodeQuickAccess)
176    . = ALIGN(128);
177    __ram_function_end__ = .;
178  } > m_qacode
179
180  __NDATA_ROM = __ram_function_flash_start + (__ram_function_end__ - __ram_function_start__);
181  .ncache.init : AT(__NDATA_ROM)
182  {
183    __noncachedata_start__ = .;   /* create a global symbol at ncache data start */
184    *(NonCacheable.init)
185    . = ALIGN(4);
186    __noncachedata_init_end__ = .;   /* create a global symbol at initialized ncache data end */
187  } > m_ncache
188  . = __noncachedata_init_end__;
189  .ncache :
190  {
191    *(NonCacheable)
192    . = ALIGN(4);
193    __noncachedata_end__ = .;     /* define a global symbol at ncache data end */
194  } > m_ncache
195
196  __DATA_END = __NDATA_ROM + (__noncachedata_init_end__ - __noncachedata_start__);
197  text_end = ORIGIN(m_text) + LENGTH(m_text);
198  ASSERT(__DATA_END <= text_end, "region m_text overflowed with text and data")
199
200  .qadata :
201  {
202    . = ALIGN(4);
203    *(DataQuickAccess)       /* quick access data section */
204    . = ALIGN(4);
205  } > m_data2
206
207  /* Uninitialized data section */
208  .bss :
209  {
210    /* This is used by the startup in order to initialize the .bss section */
211    . = ALIGN(4);
212    __START_BSS = .;
213    __bss_start__ = .;
214    *(m_usb_dma_noninit_data)
215    *(.bss)
216    *(.bss*)
217    *(COMMON)
218    . = ALIGN(4);
219    __bss_end__ = .;
220    __END_BSS = .;
221  } > m_data
222
223  .heap :
224  {
225    . = ALIGN(8);
226    __end__ = .;
227    PROVIDE(end = .);
228    __HeapBase = .;
229    . += HEAP_SIZE;
230    __HeapLimit = .;
231    __heap_limit = .; /* Add for _sbrk */
232  } > m_heap
233
234  .stack :
235  {
236    . = ALIGN(8);
237    . += STACK_SIZE;
238  } > m_data
239
240  /* Initializes stack on the end of block */
241  __StackTop   = ORIGIN(m_data) + LENGTH(m_data);
242  __StackLimit = __StackTop - STACK_SIZE;
243  PROVIDE(__stack = __StackTop);
244
245  .ARM.attributes 0 : { *(.ARM.attributes) }
246}
247