1/**************************************************************************/
2/*                                                                        */
3/*       Copyright (c) Microsoft Corporation. All rights reserved.        */
4/*                                                                        */
5/*       This software is licensed under the Microsoft Software License   */
6/*       Terms for Microsoft Azure RTOS. Full text of the license can be  */
7/*       found in the LICENSE file at https://aka.ms/AzureRTOS_EULA       */
8/*       and in the root directory of this software.                      */
9/*                                                                        */
10/**************************************************************************/
11
12
13/**************************************************************************/
14/**************************************************************************/
15/**                                                                       */
16/** ThreadX Component                                                     */
17/**                                                                       */
18/**   Thread                                                              */
19/**                                                                       */
20/**************************************************************************/
21/**************************************************************************/
22
23#ifdef TX_INCLUDE_USER_DEFINE_FILE
24#include "tx_user.h"
25#endif
26
27    .text
28    .align 4
29    .syntax unified
30/**************************************************************************/
31/*                                                                        */
32/*  FUNCTION                                               RELEASE        */
33/*                                                                        */
34/*    _tx_thread_stack_build                           Cortex-Mx/GNU      */
35/*                                                           6.2.1        */
36/*  AUTHOR                                                                */
37/*                                                                        */
38/*    Scott Larson, Microsoft Corporation                                 */
39/*                                                                        */
40/*  DESCRIPTION                                                           */
41/*                                                                        */
42/*    This function builds a stack frame on the supplied thread's stack.  */
43/*    The stack frame results in a fake interrupt return to the supplied  */
44/*    function pointer.                                                   */
45/*                                                                        */
46/*  INPUT                                                                 */
47/*                                                                        */
48/*    thread_ptr                            Pointer to thread control blk */
49/*    function_ptr                          Pointer to return function    */
50/*                                                                        */
51/*  OUTPUT                                                                */
52/*                                                                        */
53/*    None                                                                */
54/*                                                                        */
55/*  CALLS                                                                 */
56/*                                                                        */
57/*    None                                                                */
58/*                                                                        */
59/*  CALLED BY                                                             */
60/*                                                                        */
61/*    _tx_thread_create                     Create thread service         */
62/*                                                                        */
63/*  RELEASE HISTORY                                                       */
64/*                                                                        */
65/*    DATE              NAME                      DESCRIPTION             */
66/*                                                                        */
67/*  06-02-2021      Scott Larson            Initial Version 6.1.7         */
68/*  03-08-2023      Scott Larson            Include tx_user.h,            */
69/*                                            resulting in version 6.2.1  */
70/*                                                                        */
71/**************************************************************************/
72// VOID   _tx_thread_stack_build(TX_THREAD *thread_ptr, VOID (*function_ptr)(VOID))
73// {
74    .global  _tx_thread_stack_build
75    .thumb_func
76_tx_thread_stack_build:
77
78    /* Build a fake interrupt frame.  The form of the fake interrupt stack
79       on the Cortex-M should look like the following after it is built:
80
81       Stack Top:
82                       LR          Interrupted LR (LR at time of PENDSV)
83                       r4          Initial value for r4
84                       r5          Initial value for r5
85                       r6          Initial value for r6
86                       r7          Initial value for r7
87                       r8          Initial value for r8
88                       r9          Initial value for r9
89                       r10         Initial value for r10
90                       r11         Initial value for r11
91                       r0          Initial value for r0    (Hardware stack starts here!!)
92                       r1          Initial value for r1
93                       r2          Initial value for r2
94                       r3          Initial value for r3
95                       r12         Initial value for r12
96                       lr          Initial value for lr
97                       pc          Initial value for pc
98                       xPSR        Initial value for xPSR
99
100    Stack Bottom: (higher memory address)  */
101
102    LDR     r2, [r0, #16]                           // Pickup end of stack area
103    BIC     r2, r2, #0x7                            // Align frame for 8-byte alignment
104    SUB     r2, r2, #68                             // Subtract frame size
105    LDR     r3, =0xFFFFFFFD                         // Build initial LR value
106    STR     r3, [r2, #0]                            // Save on the stack
107
108    /* Actually build the stack frame.  */
109
110    MOV     r3, #0                                  // Build initial register value
111    STR     r3, [r2, #4]                            // Store initial r4
112    STR     r3, [r2, #8]                            // Store initial r5
113    STR     r3, [r2, #12]                           // Store initial r6
114    STR     r3, [r2, #16]                           // Store initial r7
115    STR     r3, [r2, #20]                           // Store initial r8
116    STR     r3, [r2, #24]                           // Store initial r9
117    STR     r3, [r2, #28]                           // Store initial r10
118    STR     r3, [r2, #32]                           // Store initial r11
119
120    /* Hardware stack follows.  */
121
122    STR     r3, [r2, #36]                           // Store initial r0
123    STR     r3, [r2, #40]                           // Store initial r1
124    STR     r3, [r2, #44]                           // Store initial r2
125    STR     r3, [r2, #48]                           // Store initial r3
126    STR     r3, [r2, #52]                           // Store initial r12
127    MOV     r3, #0xFFFFFFFF                         // Poison EXC_RETURN value
128    STR     r3, [r2, #56]                           // Store initial lr
129    STR     r1, [r2, #60]                           // Store initial pc
130    MOV     r3, #0x01000000                         // Only T-bit need be set
131    STR     r3, [r2, #64]                           // Store initial xPSR
132
133    /* Setup stack pointer.  */
134    // thread_ptr -> tx_thread_stack_ptr =  r2;
135
136    STR     r2, [r0, #8]                            // Save stack pointer in thread's
137                                                    //   control block
138    BX      lr                                      // Return to caller
139// }
140