1*** Variables ***
2${UART}                       sysbus.cr_uart1
3${URI}                        @https://dl.antmicro.com/projects/renode
4${PLATFORM}                   platforms/boards/nuvoton_npcx9m6fb_evb.repl
5
6${BOARD_WITH_LED}=  SEPARATOR=
7...  """                                                            ${\n}
8...  using "${PLATFORM}"                                            ${\n}
9...  itim32_1:                                                      ${\n}
10...  ${SPACE*4}apb2Frequency:  15000000                             ${\n}
11...  itim64:                                                        ${\n}
12...  ${SPACE*4}apb2Frequency:  15000000                             ${\n}
13...  """
14
15
16*** Test Cases ***
17Should Blink With Led
18    Execute Command             mach create
19    Execute Command             machine LoadPlatformDescriptionFromString ${BOARD_WITH_LED}
20    Execute Command             sysbus LoadELF @https://dl.antmicro.com/projects/renode/npcx9m6f_evb--zephyr-blinky.elf-s_441840-4b2511ac3dae96ad2bb3399bd0e1e7a5608ec44d
21
22    Create Terminal Tester      ${UART}   defaultPauseEmulation=true
23
24    Create LED Tester           sysbus.gpio6.red_led
25
26    Wait For Line On Uart       Booting Zephyr OS build
27    Assert LED Is Blinking      testDuration=4  onDuration=1  tolerance=0.05  offDuration=1
28
29
30Should Run TMP108
31    Execute Command             mach create
32    Execute Command             machine LoadPlatformDescription @${PLATFORM}
33    Execute Command             machine LoadPlatformDescriptionFromString "tmp108: Sensors.TMP108 @ smbus0 32"
34
35    Execute Command             sysbus LoadELF @https://dl.antmicro.com/projects/renode/npcx9m6f_evb--zephyr-sensor-tmp108.elf-s_863952-eb8c2bd632d2e0ed4531bb7ef04d880e49cdd534
36
37    Create Terminal Tester      ${UART}   defaultPauseEmulation=true
38
39    Wait For Line On Uart       *** Booting Zephyr OS build
40    Wait For Line On Uart       TI TMP108 Example, arm
41
42    Execute Command             sysbus.smbus0.tmp108 Temperature 20
43    Wait For Line On Uart       temperature is 20.0
44
45    Execute Command             sysbus.smbus0.tmp108 Temperature 18
46    Wait For Line On Uart       temperature is 18.0
47
48    Execute Command             sysbus.smbus0.tmp108 Temperature 0
49    Wait For Line On Uart       temperature is 0.0
50